Windowsでファイル名に連番付け一括変更するバッチツール

[mytab group=”01″ class=”1″ tname=”ツール”] [/mytab] [mytab group=”01″ class=”2″ tname=”ソース（参考）”]

(1)ソースコードをコピーする

筆者が作成した以下のソースコードをコピーします。
全体をマウスで範囲選択し、右クリック後に「コピー」をクリックします。

@echo off
setlocal enabledelayedexpansion

:---------------------------------------------------
:---ユーザー初期値（利用者にて値を変更して保存可能）
:---------------------------------------------------

:--- 撮影年月日（ここに入れた文字を撮影年月日とする / 値を"実行時に入力"にすると実行時入力式）
set DATETIME=実行時に入力
:--- 撮影年月日の後文字（ここに入れた文字を撮影年月日の後に入れる / 初期値はアンダーバーにしている）
set DTSUFFIX=_
:--- 連番初期値（ここに入れた数字を起点に連番を振る / 値を"実行時に入力"にすると実行時入力式）
set NUMSTART=実行時に入力
:--- 連番桁数（値1にすると1,2,3 値2にすると01,02,03 値3にすると001,002,003と連番を振る / 値3を推奨）
set NUMDIGIT=3
:--- 変換前拡張子（ここに入れた拡張子を対象に名前変換する / 値を"実行時に入力"にすると実行時入力式）
set EXTENMAE=実行時に入力
:--- 変換後拡張子（ここに入れた拡張子に名前変換 / 値を"変換前と同じ"にすると変換前と同じ拡張子に変換）
set EXTENATO=変換前と同じ

:---------------------------------------------------
:---ここから処理コマンド
:---------------------------------------------------

:---ウィンドウでユーザー入力値を受け取る
if %DATETIME% == 実行時に入力 ( set /p DATETIME=撮影年月日を入力してください：)
if %NUMSTART% == 実行時に入力 ( set /p NUMSTART=連番初期値を入力してください：)
if %EXTENMAE% == 実行時に入力 ( set /p EXTENMAE=対象拡張子を入力してください：)

:---ユーザー入力値をもとに各種変数に値をセット
set DATETIME=%DATETIME%%DTSUFFIX%
set /a i=%NUMSTART%

:---ユーザー初期値をもとに各種変数に値をセット
set /a NUMDIGIT=%NUMDIGIT%
if %EXTENATO% == 変換前と同じ ( set EXTENATO=%EXTENMAE%)

:---連番桁数の前ゼロを変数にセット
if %NUMDIGIT% geq 3 ( set KETA3=0)
if %NUMDIGIT% geq 2 ( set KETA2=0)

:---ファイル名を仮の値に変更（リネームループ防止用）
for %%F in (*.%EXTENMAE%) do (
 if not %%~xF == .bat (
  rename "%%F" "%%~nF■%%~xF"
 )
)

:---ファイル名変更（IF文で桁数を把握して前ゼロ補完）
for %%F in (*■.%EXTENMAE%) do (
 if %%~xF == .bat (
  set /a i=i-1
 ) else if !i! LSS 10 (
  rename "%%F" "%DATETIME%%KETA3%%KETA2%!i!.%EXTENATO%"
 ) else if !i! LSS 100 (
  rename "%%F" "%DATETIME%%KETA3%!i!.%EXTENATO%"
 ) else (
  rename "%%F" "%DATETIME%!i!.%EXTENATO%"
 )
 set /a i=i+1
)

(2)Windows標準のメモ帳を起動する

まず、Windowsキーを押しながらアルファベットのRキーを押します。

そして「ファイル名を指定して実行」ウィンドウが表示されたら、名前に「notepad」と入力し、OKをクリック。

(3)テキストファイルにソースを貼りつける

Windows標準のメモ帳が起動するので、右クリック後に「貼りつけ」をクリック。

すると、手順2(1)でコピーしたソースコードが貼りつけられるので、あとはメニューバーの「ファイル」内の「名前を付けて保存」をクリック。

(4)ファイル名の末尾に.batを付けて保存

まず保存先として「デスクトップ」を選択。（デスクトップ以外でもOK）

ファイル名欄に「ファイル名一括変更ツール.bat」と入れて「保存」ボタンをクリック。

ここで大事なのは、ファイル名の末尾に必ず「.bat」を付けること。それだけで、貼りつけたソースコードをプログラムと認識することができます。

(5)保存結果を確認して試し実行

デスクトップに保存された「ファイル名一括変更ツール.bat」を見て、アイコンが歯車マークになっていれば保存成功。

ソースを正しく貼りつけられたか確認するために、お試しとしてファイル「ファイル名一括変更ツール.bat」をダブルクリックするとツールが起動します。

(6)コマンドプロンプト起動確認

ツールを起動した際に、

・コマンドプロンプト（黒い画面）が開くこと
・「撮影年月日を入力してください：」メッセージが出ること

を確認できたらツール準備完了。一旦、実行せずに終了させるため右上の「×」で閉じます。
[/mytab]