Windowsでファイル名に連番付け一括変更するバッチツール

記事内に広告を含みます

画像など大量のファイルをWindowsパソコンで管理するとき、ファイル名に一括で連番を付けたいことってありますよね。

特にデジカメで撮影した写真（JPEGファイル）をパソコンで保管しておくとき、ファイル名を「日付_連番.jpg」に一括変更したいと感じたことはありませんか？

今回は「簡単に変更できる」かつ「綺麗に連番を付ける」方法として、筆者が作成したファイル名一括変更ツール（Windowsバッチ）を用いる方法を紹介します。

もともと自分自身で利用するために作成したのですが、折角ですので皆様向けに公開。使用は自己責任でお願いしますが、不安を払拭するためにソースコードを公開しましたのでご活用ください。

目次閉じる

1.当ツールで出来ること
2.ツール取得方法と初期設定
3.ツール実行方法
4.ソースコードの内容について

1.当ツールで出来ること

当ツールで出来ること（ツールの仕様）としては、

①ひとつのフォルダ内に格納したファイル全部を一括でファイル名変更する（サブフォルダ除く）
②ファイル名の頭に日付などの固定値、その後に3桁の連番を付ける（例：161103_001.jpg）
③対象拡張子（.jpgや.pngなど）を指定可能（ワイルドカード指定で全拡張子対象にもできる）

当ツールはダブルクリックして「固定値」「連番初期値」「対象拡張子」を入力してEnterするだけ。

当手順を読みながらでも初回実行まで5分程度でできる簡単なものです。

2.ツール取得方法と初期設定

まずは初回作業として、筆者が用意したツールをダウンロードします。
（もしインターネット掲載ツールの利用が怖い場合は、掲載したソースコードをファイル化していただいても構いません）

特別な知識や事前インストールは不要で、Windowsのパソコンであれば誰でも利用可能です。

[mytab group=”01″ class=”1″ tname=”ツール”]

ダウンロードリンク

ファイル名一括変更ツール
・ファイル名一括変更ツール.bat

[/mytab]
[mytab group=”01″ class=”2″ tname=”ソース（参考）”]

(1)ソースコードをコピーする

筆者が作成した以下のソースコードをコピーします。
全体をマウスで範囲選択し、右クリック後に「コピー」をクリックします。

@echo off
setlocal enabledelayedexpansion

:---------------------------------------------------
:---ユーザー初期値（利用者にて値を変更して保存可能）
:---------------------------------------------------

:--- 撮影年月日（ここに入れた文字を撮影年月日とする / 値を"実行時に入力"にすると実行時入力式）
set DATETIME=実行時に入力
:--- 撮影年月日の後文字（ここに入れた文字を撮影年月日の後に入れる / 初期値はアンダーバーにしている）
set DTSUFFIX=_
:--- 連番初期値（ここに入れた数字を起点に連番を振る / 値を"実行時に入力"にすると実行時入力式）
set NUMSTART=実行時に入力
:--- 連番桁数（値1にすると1,2,3 値2にすると01,02,03 値3にすると001,002,003と連番を振る / 値3を推奨）
set NUMDIGIT=3
:--- 変換前拡張子（ここに入れた拡張子を対象に名前変換する / 値を"実行時に入力"にすると実行時入力式）
set EXTENMAE=実行時に入力
:--- 変換後拡張子（ここに入れた拡張子に名前変換 / 値を"変換前と同じ"にすると変換前と同じ拡張子に変換）
set EXTENATO=変換前と同じ

:---------------------------------------------------
:---ここから処理コマンド
:---------------------------------------------------

:---ウィンドウでユーザー入力値を受け取る
if %DATETIME% == 実行時に入力 ( set /p DATETIME=撮影年月日を入力してください：)
if %NUMSTART% == 実行時に入力 ( set /p NUMSTART=連番初期値を入力してください：)
if %EXTENMAE% == 実行時に入力 ( set /p EXTENMAE=対象拡張子を入力してください：)

:---ユーザー入力値をもとに各種変数に値をセット
set DATETIME=%DATETIME%%DTSUFFIX%
set /a i=%NUMSTART%

:---ユーザー初期値をもとに各種変数に値をセット
set /a NUMDIGIT=%NUMDIGIT%
if %EXTENATO% == 変換前と同じ ( set EXTENATO=%EXTENMAE%)

:---連番桁数の前ゼロを変数にセット
if %NUMDIGIT% geq 3 ( set KETA3=0)
if %NUMDIGIT% geq 2 ( set KETA2=0)

:---ファイル名を仮の値に変更（リネームループ防止用）
for %%F in (*.%EXTENMAE%) do (
 if not %%~xF == .bat (
  rename "%%F" "%%~nF■%%~xF"
 )
)

:---ファイル名変更（IF文で桁数を把握して前ゼロ補完）
for %%F in (*■.%EXTENMAE%) do (
 if %%~xF == .bat (
  set /a i=i-1
 ) else if !i! LSS 10 (
  rename "%%F" "%DATETIME%%KETA3%%KETA2%!i!.%EXTENATO%"
 ) else if !i! LSS 100 (
  rename "%%F" "%DATETIME%%KETA3%!i!.%EXTENATO%"
 ) else (
  rename "%%F" "%DATETIME%!i!.%EXTENATO%"
 )
 set /a i=i+1
)